OpenGL基础学习笔记（十四）---- 材质属性
现实世界中的不同物体对光线的响应各不相同，例如金属比陶瓷更具光泽，某些材料会呈现更大的高光区域，而有些则不会。为了准确表现各种物体面对相同光源时的不同反应，OpenGL引入了材质（Material）的概念来描述物体表面特性。
我们可以为环境光（Ambient）、漫反射光（Diffuse）和镜面光（Specular）这三种光照成分分别指定一种颜色，从而实现对物体表面色彩输出的精细控制。此外，我们还会引入一个称为"光泽度"（shininess）的参数。
在片段着色器中，我们通过创建一个名为Material的结构体来组织这些变量：
#version 330 core
struct Material {
vec3 ambient;
vec3 diffuse;
vec3 specular;
float shininess;
};
uniform Material material;
接下来，我们将使用这个材质系统来完善我们的着色器逻辑。
材质配置
基于上述材质结构，我们需要更新片段着色器的计算方式。通过访问uniform变量结构体中的各个成员来进行处理。
void main()
{
// 环境光部分
vec3 ambient = lightColor * material.ambient;
// 漫反射部分
vec3 norm = normalize(Normal);
vec3 lightDir = normalize(lightPos - FragPos);
float diff = max(dot(norm, lightDir), 0.0);
vec3 diffuse = lightColor * (diff * material.diffuse);
// 镜面反射部分
vec3 viewDir = normalize(viewPos - FragPos);
vec3 reflectDir = reflect(-lightDir, norm);
float spec = pow(max(dot(viewDir, reflectDir), 0.0), material.shininess);
vec3 specular = lightColor * (spec * material.specular);
vec3 result = ambient + diffuse + specular;
FragColor = vec4(result, 1.0);
}
只需给结构体内的属性赋值即可，该结构体仅作为uniform变量的集合容器，实际赋值方法与普通uniform变量一致：
lightingShader.setVec3("material.ambient", 1.0f, 0.5f, 0.31f);
lightingShader.setVec3("material.diffuse", 1.0f, 0.5f, 0.31f);
lightingShader.setVec3("material.specular", 0.5f, 0.5f, 0.5f);
lightingShader.setFloat("material.shininess", 32.0f);
我们将环境光和漫反射光设置为合适的值，得到的效果如下所示：
光源属性调整
但观察图像发现整体亮度偏高，这是因为所有光照分量都使用了光源的完整强度。实际上，每种光照分量应根据其特性拥有不同的强度系数。我们可以分别为环境光、漫反射和镜面光添加强度因子，并将其与原光照值相乘。
vec3 ambient = vec3(0.1) * material.ambient;
同样地，可以为其他两个分量做类似处理。为此，我们定义一个新的Light结构体：
struct Light {
vec3 position;
vec3 ambient;
vec3 diffuse;
vec3 specular;
};
uniform Light light;
通常，环境光设为较小的值以避免过分突出；漫反射光设为接近最终视觉效果的值；镜面光则设为1.0以便完整反映高光。
完整片段着色器代码
#version 330 core
out vec4 FragColor;
in vec3 Normal;
in vec3 FragPos;
struct Material{
vec3 ambient;
vec3 diffuse;
vec3 specular;
float shininess;
};
struct Light{
vec3 position;
vec3 ambient;
vec3 diffuse;
vec3 specular;
};
uniform Material material;
uniform Light light;
uniform vec3 viewPos;
void main()
{
vec3 ambient = material.ambient * light.ambient;
// 漫反射部分
vec3 norm = normalize(Normal);
vec3 lightDir = normalize(light.position - FragPos);
float diff = max(dot(norm, lightDir), 0.0);
vec3 diffuse = diff * (light.diffuse * material.diffuse);
// 镜面反射部分
vec3 viewDir = normalize(viewPos - FragPos);
vec3 reflectDir = reflect(-lightDir, norm);
float spec = pow(max(dot(viewDir, reflectDir), 0.0), material.shininess);
vec3 specular = light.specular * (material.specular * spec);
vec3 result = (ambient + diffuse + specular);
FragColor = vec4(result, 1.0);
}
我们可以利用此着色器渲染一个颜色动态变化的立方体：
while (!glfwWindowShouldClose(window)) {
// per-frame time logic
float currentFrame = static_cast<float>(glfwGetTime());
deltaTime = currentFrame - lastFrame;
lastFrame = currentFrame;
// 输入处理
key_callback(window);
// 渲染操作
glClearColor(0.1f, 0.1f, 0.1f, 1.0f);
glClear(GL_COLOR_BUFFER_BIT | GL_DEPTH_BUFFER_BIT);
// 动态光源位置
Object.use();
glm::vec3 lightColor;
lightColor.x = sin(glfwGetTime() * 2.0f);
lightColor.y = sin(glfwGetTime() * 0.7f);
lightColor.z = sin(glfwGetTime() * 1.3f);
glm::vec3 diffuseColor = lightColor * glm::vec3(0.5f);
glm::vec3 ambientColor = diffuseColor * glm::vec3(0.2f);
Object.setvec3("viewPos", MainCamera.Position);
Object.setvec3("material.ambient", glm::vec3(1.0f, 0.5f, 0.31f));
Object.setvec3("material.diffuse", glm::vec3(1.0f, 0.5f, 0.31f));
Object.setvec3("material.specular", glm::vec3(0.5f, 0.5f, 0.5f));
Object.setfloat("material.shininess", 32.0f);
Object.setvec3("light.ambient", ambientColor);
Object.setvec3("light.diffuse", diffuseColor);
Object.setvec3("light.specular", glm::vec3(1.0f, 1.0f, 1.0f));
Object.setvec3("light.position", lightPos);
// 视角与投影变换
glm::mat4 projection = glm::perspective(glm::radians(MainCamera.Zoom), (float)800 / (float)600, 0.1f, 100.0f);
glm::mat4 view = MainCamera.GetMatrix();
Object.setmat4("projection", projection);
Object.setmat4("view", view);
// 模型变换
glm::mat4 model = glm::mat4(1.0f);
Object.setmat4("model", model);
// 绘制立方体
glBindVertexArray(VAO);
glDrawArrays(GL_TRIANGLES, 0, 36);
// 同时绘制光源对象
Light.use();
Light.setmat4("projection", projection);
Light.setmat4("view", view);
model = glm::mat4(1.0f);
model = glm::translate(model, lightPos);
model = glm::scale(model, glm::vec3(0.2f));
Light.setmat4("model", model);
glBindVertexArray(LightVAO);
glDrawArrays(GL_TRIANGLES, 0, 36);
glfwSwapBuffers(window);
glfwPollEvents();
}
